社員名簿/計算式項目の実装例一覧
社員名簿>運用管理>項目・レイアウト編集にて設定できる計算式の実例を紹介します。
以下の内容を参考に、貴社のご運用に合わせてご活用ください。
👉計算式項目の代行プランのご案内
以下のお問い合わせにつきましては、お見積りのうえ別途料金を頂戴しております。
・計算式項目の作成代行
・計算式項目の修正代行
・計算式項目の確認代行
上記代行のご依頼は、担当のカスタマーサクセスまでお問い合わせください。
計算式項目の設定方法について
- {}内は計算の引数となるデータが格納されている項目名が入ります 「評価スコア>2021年度>上期評価スコア」のように、大→小項目の順で項目名を>でつないでいきます
- 引数として、テキスト、プルダウン、数値、日付が使えます
設定に必要な権限等、詳細につきましてはこちらをご覧ください。
目次
1.年齢
2.在籍期間
3.在籍月数
4.ある期日までの残日数を計算する
5.評価の点数を標語に変換する
6.保持している資格の数を計算する
年齢
ISBLANK({プロフィール>生年月日}) ? '' : DATEDIF({プロフィール>生年月日}, NOW(), 'Y')
計算結果タイプ：数値
単位設定：あり「歳」
小数点桁数：0
在籍期間
①入社日 から 本日 までの期間を算出する場合
ISBLANK({入退社・雇用状況>入社日}) ? '' : TEXT(DATEDIF({入退社・雇用状況>入社日}, NOW(), 'Y'), '??') + '年' + TEXT(DATEDIF({入退社・雇用状況>入社日}, NOW(), 'M')%12, '??') + 'ヶ月'
計算結果タイプ：文字列
②入社日 から 退職日 までの期間を算出する場合
ISBLANK({入退社・雇用状況>入社日}) ? '' : ISBLANK({入退社・雇用状況>退職状況>退職日}) ? '' : (TEXT(DATEDIF({入退社・雇用状況>入社日}, {入退社・雇用状況>退職状況>退職日}, 'Y'), '??') + '年' + TEXT(DATEDIF({入退社・雇用状況>入社日}, {入退社・雇用状況>退職状況>退職日}, 'M')%12, '??') + 'ヶ月')
計算結果タイプ：文字列
③退職日項目が空欄の場合は①、入力されている場合は②を算出する
ISBLANK({入退社・雇用状況>入社日}) ? '0' : (ISBLANK({入退社・雇用状況>退職状況>退職日}) ? TEXT(DATEDIF({入退社・雇用状況>入社日}, NOW(), 'Y'), '??') + '年' + TEXT(DATEDIF({入退社・雇用状況>入社日}, NOW(), 'M')%12, '??') + 'ヶ月' : TEXT(DATEDIF({入退社・雇用状況>入社日}, {入退社・雇用状況>退職状況>退職日}, 'Y'), '??') + '年' + TEXT(DATEDIF({入退社・雇用状況>入社日}, {入退社・雇用状況>退職状況>退職日}, 'M')%12, '??') + 'ヶ月')
計算結果タイプ：文字列
💡よくあるご質問
Q：入社日が2021/4/1、退職日が2022/3/31の場合、0年11ヶ月と表示される。1年0ヶ月と表示させたい。
A：HRBrainでは、入社日が2021/4/1の場合、退職日が2022/4/1で1年と算出する仕様です。
1年0ヶ月と算出するには、EDATE関数を使用して、退職日を1日後扱いにすることで算出結果を+1ヶ月とする必要があります。
EDATE関数を使用し、資格取得日から特定日数後の日付を算出する
EDATE({入退社・雇用状況>退職日}, 1, 'D')
計算式サンプル
「③退職日項目が空欄の場合は①、入力されている場合は②を算出する」にEDATE関数を組み込んだ場合の計算式は以下の通りです。
ISBLANK({入退社・雇用状況>入社日}) ? '0' : (ISBLANK({入退社・雇用状況>退職状況>退職日}) ? TEXT(DATEDIF({入退社・雇用状況>入社日}, NOW(), 'Y'), '??') + '年' + TEXT(DATEDIF({入退社・雇用状況>入社日}, NOW(), 'M')%12, '??') + 'ヶ月' : TEXT(DATEDIF({入退社・雇用状況>入社日}, EDATE({入退社・雇用状況>退職状況>退職日}, 1, 'D'), 'Y'), '??') + '年' + TEXT(DATEDIF({入退社・雇用状況>入社日}, EDATE({入退社・雇用状況>退職状況>退職日}, 1, 'D'), 'M')%12, '??') + 'ヶ月')
EDATE関数の詳細は以下のページをご覧ください。
在籍月数
ISBLANK({入退社・雇用状況>入社日}) ? '' : DATEDIF({入退社・雇用状況>入社日}, NOW(), 'M')
計算結果タイプ：数値
単位設定：あり「ヶ月」
小数点桁数：0
ある期日までの残日数を計算する
資格の有効期限が切れる前にフラグを出したい
①有効期限までの日数を算出する
ISBLANK({免許期限管理>有効期限}) ? '' : DATEDIF(NOW(), {免許期限管理>有効期限}, 'D')
計算結果タイプ：数値
単位設定：あり「日」
小数点桁数：0
②有効期限までの日数が30日を切っていたら「免許更新」と表示させる
ISBLANK({免許期限管理>有効期限}) ? '' : ({免許期限管理>有効期限までの日数} < 30 ? '免許更新' : '')
計算結果タイプ：文字列
※[有効期限]の項目は日付項目で作成してください。
▷社員名簿/項目・レイアウト編集機能について>各項目について>■小項目
定年退職の前にフラグを出したい
①生年月日をもとに、年齢を月数で表示させる
ISBLANK({定年退職予定管理>生年月日}) ? '' : DATEDIF({定年退職予定管理>生年月日}, NOW(), 'M')
計算結果タイプ：数値
②60歳を迎える日の3ヶ月前になったら「！」を表示させる
ISBLANK({定年退職予定管理>年齢算出}) ? '' : {定年退職予定管理>年齢算出} >= 717 ? '！' : ''
計算結果タイプ：文字列
評価の点数を標語に変換する
以下の画像内、[総合スコア（上期・下期平均）]のスコアと標語に以下のロジックがある場合、スコアを記入した際標語を自動的に表示させる
・90点以上：S
・80点以上：A
・70点以上：B
・60点以上：C
・50点以上：D
・49点以下：E
①上期評価スコアと下期評価スコアの平均点を算出する
({評価結果>上期評価スコア} + {評価結果>下期評価スコア})/2
計算結果タイプ：数値
単位設定：あり「点」
小数点桁数：1
②[総合スコア（上期・下期平均）]の点数によってSからEの標語を返す
{評価結果>総合スコア（上期・下期平均）} >= 90 ? 'S' : ({評価結果>総合スコア（上期・下期平均）} >= 80 ? 'A' : ({評価結果>総合スコア（上期・下期平均）} >= 70 ? 'B' : ({評価結果>総合スコア（上期・下期平均）} >= 60 ? 'C' : ({評価結果>総合スコア（上期・下期平均）} >= 50 ? 'D' : 'E'))))
計算結果タイプ：文字列
保持している資格の数を計算する
({資格管理>資格A} == ['◯'] ? 1 : 0) + ({資格管理>資格B} == ['◯'] ? 1 : 0) + ({資格管理>資格C} == ['◯'] ? 1 : 0)
※各項目に「◯」が入っていれば1と換算し合計
計算結果タイプ：数値
単位設定：あり「個」
小数点桁数：0